Re: How to structure installation of TCPIP related products

"JF Mezei" <jfmezei.spamnot@xxxxxxxxxxxxx> wrote in message news:d06c6$4684af01$cef8887a$29453@xxxxxxxxxxxxxxx
Say I have an utility that runs as a server/deamon to receive TCP/UDP calls.

With TCPIP Services before 5.3, I have to manually start the process and it declares itself listener to port xxx.

With 5.3 and later, I can define the service with TCPIP> SET SERVICE, including the username, startup file and log file etc. And when the stack is brought up and/or first incoming calls comes in, the process is started and processes the data.

You can create services like this way earlier than V5.3.


And I have absolutely no idea how it works with multinet or the other stacks.

Any hints on how to structure the installation procedure such that it is clean and easy for the system manager no matter what stack he has ?

Here's what we use to define the JAMS service. It works with UCX, TCPIP, MultiNet and TCPWare.

$!
$! Define the JAMS Server service
$!
$ IF (P1 .NES. "")
$ THEN
$ TCPIP_PRODUCT = P1
$ TCPIPCMD = P1
$ GOTO DEFINE_'TCPIP_PRODUCT'
$ ENDIF
$!
$! Figure out which TCP/IP Product is being used
$!
$ FOUND_COUNT = 0
$!
$ IF (F$SEARCH("SYS$STARTUP:UCX$STARTUP.COM") .NES. "")
$ THEN
$ FOUND_COUNT = 1
$ TCPIPCMD := UCX
$ TCPIP_PRODUCT = "UCX"
$ ENDIF
$!
$ IF (F$SEARCH("SYS$STARTUP:TCPIP$STARTUP.COM") .NES. "")
$ THEN
$ FOUND_COUNT = 1
$ TCPIPCMD := TCPIP
$ TCPIP_PRODUCT = "TCPIP"
$ ENDIF
$!
$ IF (F$SEARCH("MULTINET:START_MULTINET.COM") .NES. "")
$ THEN
$ FOUND_COUNT = FOUND_COUNT + 1
$ TCPIP_PRODUCT = "MULTINET"
$ ENDIF
$!
$ IF (F$SEARCH("TCPWARE:TCPWARE_LOGICALS.COM") .NES. "")
$ THEN
$ FOUND_COUNT = FOUND_COUNT + 1
$ TCPIP_PRODUCT = "TCPWARE"
$ ENDIF
$!
$! Make sure we found one, and only one.
$!
$ IF (FOUND_COUNT .EQ. 0)
$ THEN
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "You do not have a supported TCP/IP product installed."
$ WRITE SYS$OUTPUT ""
$ EXIT
$ ENDIF
$!
$ IF (FOUND_COUNT .GT. 1)
$ THEN
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "You have more than one supported TCP/IP product installed."
$ WRITE SYS$OUTPUT "You must manually configure the JAMS Service"
$ WRITE SYS$OUTPUT ""
$ EXIT
$ ENDIF
$!
$! Go do it
$ GOTO DEFINE_'TCPIP_PRODUCT'
$!
$! Compaq TCP/IP Services (AKA UCX)
$!
$DEFINE_TCPIP:
$DEFINE_UCX:
$!
$ WRITE SYS$OUTPUT "Defining TCP/IP service"
$ TCPIPCMD SET SERVICE -
/FILE=JAMS_COM:JAMS_SERVER_TCPIP.COM -
/PORT=773 -
/PROCESS_NAME=JAMS_SRV -
/USER_NAME=SYSTEM -
/FLAGS=(LISTEN, MULTITHREAD) -
/LOG_OPTIONS=ALL -
/LIMIT=10 -
JAMS
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "You must add this command:"
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT " $ ''TCPIPCMD' ENABLE SERVICE JAMS"
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "to SYS$STARTUP:SYSTARTUP_VMS.COM"
$ WRITE SYS$OUTPUT ""
$ EXIT
$!
$!
$! Process Multinet
$!
$DEFINE_MULTINET:
$ WRITE SYS$OUTPUT "Defining Multinet service"
$ MULTINET CONFIGURE/SERVER
ADD JAMS
TCP
773
JAMS_COM:JAMS_SERVER_TCPIP.COM
SET FLAG UCX_SERVER
SET USERNAME SYSTEM
SAVE
RESTART
$ EXIT
$!
$!
$! Process TCPWare
$!
$DEFINE_TCPWARE:
$ WRITE SYS$OUTPUT "Defining TCPware service"
$ RUN TCPWARE:NETCU.EXE
ADD SERVICE 773 BG_TCP/USERNAME=SYSTEM/INPUT=JAMS_COM:JAMS_SERVER_TCPIP.COM
EXIT
$ EXIT
$!


.

Relevant Pages